ASP Content Linking 组件
实例
本例会构建一个内容列表。
<html>
<body>
<p>下面的例子构建了一个内容列表：</p>
<%
dim c
dim i
set nl=server.createobject("MSWC.Nextlink")
c = nl.GetListCount("/example/aspe/links.txt")
i = 1
%>
<ul>
<%do while (i <= c) %>
<li><a href="<%=nl.GetNthURL("/example/aspe/links.txt", i)%>">
<%=nl.GetNthDescription("/example/aspe/links.txt", i)%></a>
<%
i = (i + 1)
loop
%>
</ul>
<p>文本文件包含页面 URL 的列表和链接描述。
每行文本针对一个页面。
请注意，URL 和描述必须由 TAB 字符分隔。
</p>
<p>
<a href="/example/aspe/links.txt">查看 links.txt</a>
</p>
</body>
</html>
本例使用 Content Linking 组件在一个文本文件所列的页面间进行导航。
<html>
<body>
<h1>这是页面 1</h1>
<%
Set nl=Server.CreateObject("MSWC.NextLink")
If (nl.GetListIndex("/example/aspe/links2.txt")>1) Then
%>
<a href="<%Response.Write(nl.GetPreviousURL("/example/aspe/links2.txt"))%>">
上一页
</a>
<%End If%>
<a href="<%Response.Write(nl.GetNextURL("/example/aspe/links2.txt"))%>">
下一页
</a>
<p>本例使用 Content Linking 组件
对文本文件中的 URL 进行导航。</p>
<p><a href="/example/aspe/links2.txt">查看 links2.txt</a></p>
</body>
</html>
ASP Content Linking 组件
ASP Content Linking 组件用于创建快捷便利的导航系统。
Content Linking 组件会返回一个 Nextlink 对象，这个对象用于容纳需要导航网页的一个列表。
语法
<%
Set nl=Server.CreateObject( "MSWC.NextLink" )
%>
首先，我们会创建文本文件 - "links.txt"。此文件包含需要导航的页面的相关信息。页面的排列顺序应该与它们的显示顺序相同，并包含对每个文件的描述（使用制表符来分隔文件名和描述信息）。
注释：如果你希望向列表添加文件信息，或者改变在列表中的页面顺序，那么你需要做的所有事情仅仅是修改这个文本文件而已！然后导航系统会自动地更新！
"links.txt":
asp_intro.asp ASP 简介
asp_syntax.asp ASP 语法
asp_variables.asp ASP 变量
asp_procedures.asp ASP 程序
请在上面列出的页面中放置这行代码：<!-- #include file="nlcode.inc"-->。这行代码会在 "links.txt" 中列出每个页面上引用下面这段代码，这样导航就可以工作了。
"nlcode.inc":
<%
'Use the Content Linking Component
'to navigate between the pages listed
'in links.txt
dim nl
Set nl=Server.CreateObject("MSWC.NextLink")
if (nl.GetListIndex("links.txt")>1) then
Response.Write("<a href='" & nl.GetPreviousURL("links.txt"))
Response.Write("'>Previous Page</a>")
end if
Response.Write("<a href='" & nl.GetNextURL("links.txt"))
Response.Write("'>Next Page</a>")
%>
ASP Content Linking 组件的方法
GetListCount 方法
返回内容链接列表文件中所列项目的数目：
<%
dim nl,c
Set nl=Server.CreateObject("MSWC.NextLink")
c=nl.GetListCount("links.txt")
Response.Write("There are ")
Response.Write(c)
Response.Write(" items in the list")
%>
输出：
There are 4 items in the list
GetListIndex 方法
返回在内容链接列表文件中当前文件的索引号。第一个条目的索引号是 1。假如当前页面不在列表文件中，则返回 0。
例子
<%
dim nl,c
Set nl=Server.CreateObject("MSWC.NextLink")
c=nl.GetListIndex("links.txt")
Response.Write("Item number ")
Response.Write(c)
%>
输出：
Item number 3
GetNextDescription 方法
返回在内容链接列表文件中所列的下一个条目的文本描述。假如在列表文件中没有找到当前文件，则列表中最后一个页面的文本描述。
例子
<%
dim nl,c
Set nl=Server.CreateObject("MSWC.NextLink")
c=nl.GetNextDescription("links.txt")
Response.Write("Next ")
Response.Write("description is: ")
Response.Write(c)
%>
输出：Next description is: ASP Variables
GetNextURL 方法
返回在内容链接列表文件中所列的下一个条目的 URL。假如在列表文件中没有找到当前文件，则列表中最后一个页面的 URL。
例子
<%
dim nl,c
Set nl=Server.CreateObject("MSWC.NextLink")
c=nl.GetNextURL("links.txt")
Response.Write("Next ")
Response.Write("URL is: ")
Response.Write(c)
%>
输出：Next URL is: asp_variables.asp
GetNthDescription 方法
返在内容链接列表文件中所列的第 N 个页面的描述信息。
例子
<%
dim nl,c
Set nl=Server.CreateObject("MSWC.NextLink")
c=nl.GetNthDescription("links.txt",3)
Response.Write("Third ")
Response.Write("description is: ")
Response.Write(c)
%>
输出：Third description is: ASP Variables
GetNthURL 方法
返在内容链接列表文件中所列的第 N 个页面的 URL。
例子
<%
dim nl,c
Set nl=Server.CreateObject("MSWC.NextLink")
c=nl.GetNthURL("links.txt",3)
Response.Write("Third ")
Response.Write("URL is: ")
Response.Write(c)
%>
输出：Third URL is: asp_variables.asp
GetPreviousDescription 方法
返回在内容链接列表文件中所列前一个条目的文本描述。假如在列表文件中没有找到当前文件，则列表中第一个页面的文本描述。
例子
<%
dim nl,c
Set nl=Server.CreateObject("MSWC.NextLink")
c=nl.GetPreviousDescription("links.txt")
Response.Write("Previous ")
Response.Write("description is: ")
Response.Write(c)
%>
输出：Previous description is: ASP Variables
GetPreviousURL 方法
返回在内容链接列表文件中所列前一个条目的 URL。假如在列表文件中没有找到当前文件，则列表中第一个页面的URL。
例子
<%
dim nl,c
Set nl=Server.CreateObject("MSWC.NextLink")
c=nl.GetPreviousURL("links.txt")
Response.Write("Previous ")
Response.Write("URL is: ")
Response.Write(c)
%>
输出：Previous URL is: asp_variables.asp